*save_checkpoint

*text_image chap_3.png center Chapter Three
*temp toldzagreusoff false
*temp deniedrobe false
*temp morpheusmock false
*temp annoyedtheron false
*temp startledtheron false
*temp friendlytheron false
*temp reluctant false
*temp silent false


In the end, Zagreus finds you. 

His hunter's footsteps are like the breeze on grass, too gentle to make a sound. You @{(cunning > 55) notice them anyway|don't notice them, and his sudden presence between a couple of leafy trees startles you}.

@{(cunning > 55) "Did you really think you could sneak up on me?"|"Show off," you gasp, clutching at your chest}.

He waves you off. "Sent to fetch me, I see."

"Much to my @{(Zagreus > 55) relief."|annoyance," you huff}.

He @{(Zagreus > 55) grins and links arms with you|gives you a little smirk}.

*page_break Return To The Pond

"Where's your satyr friend?" you ask, glancing behind you.

Zagreus's expression sours. "Went off in a huff."

"How so?"

"Apparently, suggesting we find somewhere more intimate to discuss a private matter means something different in Olympus." He shrugs. "When he realized that's all I actually wanted to do, he was very offended."

You're certain your eyebrows graze your hairline.

"What? If you're to marry Ares, we should know what kind of god he really is. Not the poets' exalted version, nor the one he presents in front of his parents."

"So you asked an Olympian harpist to paint a more balanced picture?" you wonder with a frown.

"The triton I spent the night with said he'd heard him refer to Ares as feeble-minded and helpless. I thought I'd find out why."

You come to an abrupt halt, @{(Zagreus > 55) warmed|surprised} by his concern. And impressed by his sleuthing.

Never mind the merits of his petteia strategy, or lack thereof. @{(petteia) You ought not to underestimate him so readily|Looks like he's more than capable of fighting his own battles–and, it would seem, yours|It would appear he's just as protective of you as you are of him|You ought not to underestimate him so readily|You ought not to underestimate him so readily}.

*fake_choice
    #I hug him.
        *set Zagreus %+15
        "Hey, you're ruining my chiton's fanciful draping," he complains, gently patting your back.

        You squeeze him tighter. "Oh, shush."
    #I thank him.
        *set Zagreus %+10
        "Zagreus, that's very thoughtful of you." You meet his gaze, letting your appreciation shine through. "Thank you."

        He blushes at your earnestness.

        "Oh, it's just a little subterfuge. Nothing to gush about," he dismisses you.

        But he @{(Zagreus > 55) gives your arm a grateful squeeze|perks up, smiling at the trees}.
    #I tease him.
        *set Zagreus %+5
        "Look at you, engaging in subterfuge," you coo. "Father would be so proud."

        "Please don't tell him. It'll lead to him developing expectations," he shudders. "I would rather not have to deal with those."

        You shake your head.
    #I tell him off for meddling.
        *set Zagreus %-5
        *set dutiful %+5
        *set toldzagreusoff true
        "You shouldn't have done that. It's none of your concern, for one, and it could land you in a lot of trouble."

        He scowls, gently tugging at one of the branches curling over him. "I'd hardly call Mother and Father lecturing me about propriety trouble. Besides, they're the ones who taught us the usefulness of subterfuge."

        His irritation sours the air between you.

"Well, did you? Find out why he called him that, I mean," you ask, resuming your @{(toldzagreusoff) journey. You meant what you said, but since he already made it his concern, you might as well know|journey}.

He @{(toldzagreusoff) glares at you and, for a moment, you think he won't tell you. Then he sighs and relents|grimaces}.

"He played at one of Dionysus's salons where Athena entertained everyone with stories of his cowardice in battle. He was merely repeating what he'd heard her say."

Ouch. His own sister, ridiculing him so in public.

*page_break

@{(toldzagreusoff) Zagreus's glare sharpens, as though he can read your thoughts–and relates to them|"I know," Zagreus agrees, reading your thoughts}.

@{(toldzagreusoff) "Oh, please," you wave him off. "I'm not [i]that[/i] bad."|"Good work," you praise him.}

@{(toldzagreusoff) "Thank the Fates," he grumbles|"Why, thank you," he beams}. Then he grows serious anew. "I also found out that he may have had more than just a fling with a certain goddess of love. I'm not one to judge that sort of thing, having dabbled in such prickly affairs myself and such, but I hear it's the cause of much strife and tension."

"Tell me about it," you sigh. 

It's his turn to come to an abrupt halt. "Did something happen? Are you alright?"

@{(toldzagreusoff) "Of course I'm alright," you snap, offended that he thought you might not be. Then you sigh and resume walking at pace.|"I'm alright," you reassure him.} "Come, I'll update you on the way."

*page_break

Your father rises as soon as you return.

"Zeus, thank you for being such a fine host. You honor us greatly," he says, "but I'm afraid duty calls."
    
When he also rises, Zeus has the jovial demeanor of a father bidding farewell to his brood. "You work too hard, my friend."
    
"Death works harder," Hades dismisses him.

Meanwhile, the Queens hug each other, making promises to write more and give regards to their respective courts.

"I must pay your realm a visit next," Zeus adds. 

Your father smiles politely, even though he knows it's an empty platitude. Most Olympians rarely visit the Underworld. Death dwells there, and they draw their power from the living alone. 

Only by eating the realm's fruit may they remain without falling ill, and eventually losing their divine strength. And after, they can't stray too far from its reach.

You can't imagine being subject to such restrictions. Though you're strongest in the nightmares woven by your own hand, you're a Messenger goddess; free to travel from one realm to the next unimpeded.

*page_break For Now

After bidding everyone farewell, Zeus and Hera escort you to the courtyard, where your father's chariot awaits.

The horses' ears prick back, eager for his orders.

He lets Zagreus and your mother pile in first. They wave at the Olympians as they do, bickering under their breaths.

Before you join them, Hades leans in close, so that only you can hear his next words. 

*if outcome = "madolympians"
    "Do not underestimate Zeus, daughter. He may seem amiable. Harmless, even. But he didn't become King by making friends."

    The scar across his eye glints in the bright light, and a remote expression clouds his face. You get the impression his mind is somewhere else, somewhere that makes him look even more glum than usual.

    @{(parentsrel) "Father?" He blinks, as if woken from a slumber, then brings his hand to your cheek|"I would never. Do you take me for a fool?" I say, annoyed that he thinks I need the reminder|You clear your throat. He snaps out of it, but sorrow lingers on his face}.
    *goto main09
*elseif outcome = "defendedmortals"
    "It was unwise, to challenge Zeus like that."

    There is no anger in his voice, only caution.

    "Isn't it our job to protect mortals? Dismissing their suffering was cruel," @{(parentsrel) you say softly|you grunt, struggling to keep your voice down|you counter}.

    "And what good does it do them, to anger the god responsible for the welfare of their crops?"

    @{(parentsrel) He's right, as always|You must admit it's a good point|You frown; he isn't wrong}.
    *goto main09
*elseif outcome = "defendedares"
    "It was very noble of you to speak on Ares's behalf."

    There is pride in his voice, but also caution. 
    
    @{(parentsrel) "What is it, father?"|"Out with the rest already," you hiss|"But…." You gesture for him to continue}.

    "You would do well to determine why it is you did so, and be upfront with him about it."

    @{(parentsrel) You nod, grateful for the counsel|You roll your eyes, bristling against the counsel|You frown, turning his words over}.
    *goto main09
*else
    "You did well not to antagonize Zeus, daughter. He's a useful ally, if not always the most agreeable."

    Pride gleams in the dark depths of his eyes.

    @{(parentsrel) Your chest swells with joy, and you smile at him warmly|Impressing him is no easy feat. It pleases you to have managed it, despite yourself|You nod, glad you managed to impress him}.
    *goto main09

*label main09
*page_break

He takes the reins, beckoning you onboard.

You hesitate. The official portion of the feast is over. There's no more propriety to abide by, no more potential future husbands to impress. You could ride back with Zagreus and your parents, enjoy their company and the views. Or you could fly back yourself, flex your @{(flightstyle) wings|shadows|feet} a little before your nightmare run.

Which do you choose?

*choice
    #Fly myself home. I fancy a work out.
        *set fitness %+10
        *goto soloflight
    #Fly myself home. I need some space from my family.
        *set parents %-5
        *set dutiful %-5
        *goto soloflight
    #Take the carriage. It sends a message of unity to the realms.
        *set leadership %+10
        *goto familyflight
    #Take the carriage. I'd rather travel with my family.
        *set parents %+10
        *set Zagreus %+5
        *goto familyflight

*label soloflight

"See you at home," you tell them.

Before your mother can protest, Hades gives the reins a pull and the horses take off, dragging the chariot up and across the sky.

You @{(flightstyle) spread your wings|summon your shadows|gently kick the grass} and follow suit.

By the time you reach the clouds, the chariot is nothing but a glint in the distance. There's no point trying to catch up. No god is faster than Hades's horses. Not even Hermes.

Instead, you @{(flightstyle) beat your wings|weave a shadow path|glide from cloud to cloud}, smiling against the wind. 
*goto backhome

*label familyflight

You take your place behind your father. He tugs on the reins and the horses take off, dragging the chariot up and across the sky

"I'm not being prudish," you hear your mother bemoan. "I'm simply asking you to show a modicum of restraint."

"Oh, Mother. I can be restrained alright."

@{(parentsrel) You hide your smile behind a sigh|"You walked right into that one," you tell her|You pat her shoulder commiseratively}. 

Olympus is nothing but a glint in the distance.

The breeze toys with your hair and the clouds gently brush your skin. It feels nice. Peaceful, even.

You might as well enjoy it while it lasts.

*label backhome
*page_break Fly Home

As soon as you return to your chambers, there's a soft rapping on your door.

"Come in," you call out.

The shadows around the doorframe waver when Averna sweeps into the room. Very courteous of her to knock, instead of traveling through them.

She doesn't bother greeting you. Instead, she slumps into a chair and twirls the scroll in her hand at you.

"Well, how was it?"

"Who's asking, you or my mother?"

She rolls her eyes. 

"Me, but that doesn't mean I won't share whatever you tell me with her." Her grin sharpens. "Though I could be persuaded otherwise, for the right price."

Of course.

"A price you'll demand no matter what I share, I'm sure," you grumble.

"Now that you mention it, I wouldn't mind borrowing one of your gowns tonight. I'm taking a naiad out on a date, and I don't want mine to get wet."

*fake_choice
    #"If you must."
    #"Will you be returning this one?"
        "Maybe."
    #"Absolutely not."
        *set deniedrobe true

She saunters over to your @{(deniedrobe) armoire|armoire anyway} and begins ransacking through it.

"We should get a game of petteia in soon, by the way. @{(petteia) Your brother is far too easy to beat|Your brother is far too easy to beat|That way you can fight your own battles, instead of your brother's|Your brother is far too easy to beat|That way you can fight your own battles, instead of your brother's}."

It's your turn to roll your eyes.

"Oh," Averna says, pausing her rummaging long enough to pull something from a pocket of shadow trailing her. "Iris dropped by earlier. They were in a hurry, but they asked me to give you this."

She tosses a scroll at you. Neatly rolled, with gold edges that catch the many-hued light. 

Hermes's instructions for tonight's nightmare run.

You glance at @{(hobby) your loom, fingers itching to finish your latest tapestry|the weights you keep tucked away in the corner, itching for a workout|your aulos, fingers itching to play it|the petteia board, wishing you could take Averna up on her offer}. 

Sighing, you unravel the scroll instead.

*page_break Have A Read

It's a short memo. The Messengers' Council has been under a lot of pressure lately. Probably why Hermes is sending you out tonight, even though he knew you'd be back late. 

And why his handwriting is more scrawling and disjointed than usual.

[i]Double your nightmares to Leukas tonight. Its Lord continues to skimp on worship. His island is rich in resources, yet he refuses to honor us well so that we may continue to make it so. It is paramount you remind him why he shouldn't grow too greedy before Zeus steps in.[/i]

[i]H[/i]

Another increase, then. No wonder Morpheus keeps beating you back. 

Still, how you handle tonight could cement your position in the Council, and secure you some worship.

@{(nightmares) Bring it on|Bring it on|Fates willing, of course|At the expense of mortals' wellbeing, of course|As much as it haunts you sometimes, you could use both}.

"I say you go hard on him," Averna offers, as though she can read your mind. Or, more likely, as though she already read the scroll. "Not because Hermes asked you, but because fear sharpens the mind."

What do you reply?

*fake_choice
    #"I suppose you're right."
        *set cunning %+5
        "Always."
    #"I suppose it can."
        *set diplomacy %+5
    #"But it can also fracture it."
        *set ruthless %+5
        "Well, you had better make sure it's the right dose, then," the lampad retorts. 

Shadows lap at her purple hair and sinewy arms. 

And at the pile of your gowns tossed over her shoulder.

"Those better be dry when you return them!" you call after her.

You can hear her laughing even after the shadows have swallowed her.

Sighing, you toss the scroll on your desk. Iris will retrieve it when they deliver tomorrow's instructions, and store it away in the Olympian Archives.

*page_break You Had Better Leave Too

The Lethe's surface furrows lightly when you land on the moss next to it.

Morpheus has long left. You can tell by the poppies blooming on his side of the gate. Their honeyed scent is strong, their petals full and shimmering. 

You better hurry if you want to beat him back this time.

*page_break Get To Work

Night presses down on Hellas like a kneading hand. Few hearths remain lit, and the moon cuts a slim crescent into the thick dark.

Under its silver glow, you dive into the Halfrealm. 

Your Epiali @{(epiali) slither|surge|fly|leap|crawl} towards you. Their bodies blend into whirlpool-like tendrils, broken by @{(epiali) a burst of scales here, a flash of fangs there|a jointed wing here, a furry ear there|a feathered wing here, a silver beak there|a black paw here, a furry ear there|a furry leg here, an onyx eye there}.

They wrap around you, waiting for your instructions.

The type of nightmares you send out always have an impact on worship. Your own, and the rest of the pantheon's. Zeus prefers a firm hand, one that reminds mortals of his might. To go soft on them would be frowned upon by Olympus, but perhaps they could use the reminder to give, not just take from those they protect.

Play your cards right, however, and you could snatch an extra offering or two for yourself.

What approach should your Epiali take?

*choice
    #Severe; I want mortals to fear the gods' wrath.
        You grit your teeth, empty your mind of everything but what you want your Epiali to do; reign terror on the land.

        *if ruthless > 50
            *set olympusinfluence %+10
            *set worship %+10
            *set nightmaresuccess true
            The order reverberates through them, filling them with purpose. They spread across the Halfrealm and unleash horror on the mortals treading its waters.

            Dreams shift, fears jolt awake.
            
            The certainty that, come dawn, offerings and prayers for yourself and the other gods will be made in haste settles over you. You @{(flightstyle) spread your wings wide and|cast your shadows out and|dive feet first and} follow after the daemons, ready to wreak havoc of your own.
            *goto nightmaresuccess
        *else
            *set olympusinfluence %-10
            *set worship %-5
            But the day weighs heavy on your thoughts, tugs at them like an aggravated wasp.
            *if ruthless <= 40
                *set peoplepleaser %+10
                Images of mortals in their beds flash before your eyes. Lovers huddled close together, soldiers shivering in their tents, children clutching blankets. 
                
                They make you hesitate just as you give your Epiali the order. 

                The daemons spread across the Halfrealm. But instead of delivering a coordinated assault on the mortals treading its waters, they falter. Your doubt reverberates through them as they enter their dreams. The certainty that, come dawn, offerings and prayers will be scarce as a result settles over you.
                    
                Shame bites your cheeks, but you take some comfort in the fact mortals won't suffer by your hand.
                *goto nightmarefailure
            *else
                It makes you lose focus just as you give your Epiali the order.

                They spread into the Halfrealm. But instead of delivering a coordinated assault on the mortals treading its waters, they falter. Your doubt reverberates through them as they enter their dreams. The certainty that, come dawn, the offerings and prayers will be scarce hits you like a slap.

                Shame burns your cheeks. You'll have to be tougher next time. Not just on those you wish to bring in line, but also on yourself.
                *goto nightmarefailure
    #Soft; I don't want mortals to suffer unnecessarily.
        You spread your arms wide, empty your mind of everything but what you want your Epiali to do; go easy.

        *if dutiful < 50  
            *set peoplepleaser %+10
            *set worship %+15
            *set nightmaresuccess true
            They spread into the Halfrealm, not like a swarm–hungry and eager–but a shield.

            Dreams shift, fears stir awake. Not the ones that dwell in the Halfrealm's darkest depths, with sharp teeth and hungry eyes. The ones that are close to the surface. The ones that will make mortals grateful, not horrified, when they wake. 

            The certainty that, come dawn, offerings and prayers will be made in your honor settles over you. You don't dwell on it; it's not why you did it.
            *goto nightmaresuccess
        *else
            They hesitate, as though confused.
            *if ruthless >= 40
                *set peoplepleaser %-15
                *set worship %+10
                They are harbingers of dread. That's what you've trained them to be. They bristle against the command, eager to sow fear and reap worship. To reel them in requires a clear mind, a firm hand.

                It's too late for either. They spread across the Halfrealm, diving into dreams with glee, seeking out the fears that dwell in the darkest depths, with the sharpest teeth. You feel mortals' restlessness as terror takes hold of their psyches.

                The certainty that, come dawn, offerings and prayers will be made in haste wreaks havoc on your conscience. 
                
                You might have grown more powerful, but at what cost?
                *goto nightmarefailure
            *else
                *set olympusinfluence %-10
                *set peoplepleaser %-5
                *set worship %-10
                The day weighs heavy on your thoughts, tugs at them like an aggravated wasp.

                Seeing Ares again, Zeus's behavior at dinner, the confrontation with Aphrodite. Doubt muddles your command just as your Epiali take off.

                They delve into mortals' dreams, but they're unfocused. Unsure of whether to sow fear or gratitude. 
                
                The certainty that, come dawn, offerings and prayers will be scarce fills you with shame. 
                
                Neither the gods nor the people will have gained anything from this night, and you have only yourself to blame.
                *goto nightmarefailure
    #Sly; I want mortals to worship me more.
        A grin cuts into your cheeks as you empty your mind of everything but what you want your Epiali to do; reap worship.

        *if cunning > 50
            *set maverickgoddess %+10
            *set worship %+20
            *set skimmedworship true
            *set nightmaresuccess true
            The command ripples through them, fills them with purpose. They spread across the Halfrealm without a sound, blending into the shadows.

            Dreams shift. Fears stir in the Halfrealm's depths. Your Epiali lure them to the surface. Gently, sweetly. [i]Worship us[/i], they whisper. [i]Worship us[/i].
            
            The certainty that, come dawn, offerings and prayers will be made settles over you. Yes, the gods will get theirs. 
            
            But, more importantly, you will get yours–and then some.
            
            @{(flightstyle) You spread your wings wide and|You cast your shadows out and|You dive feet first and} follow after the daemons, ready to wreak havoc of your own.
            *goto nightmaresuccess
        *else
            *set maverickgoddess %-15
            *set worship %-15
            *if nightmares = 3
                But your thoughts trip and a shard of doubt creeps into your mind, cutting deep. This isn't how it's supposed to go. 
                
                This isn't what the Fates want of you.

                Dread floods you as your Epiali spread out, stumbling onto mortals' dreams. Their hesitation fails to drag fears from the depths.

                The certainty that you haven't hit your nightmare quota tugs at you. Worse, come dawn, there will be no prayers or offerings in your name. 
                    
                Shame burns your cheeks. You'll have to be wilier next time if you want to succeed.
                *goto nightmarefailure
            *elseif (nightmares = 4) or (nightmares =5)
                *set peoplepleaser %+5
                But your thoughts trip and guilt slips in. You picture mortals in their beds. Lovers huddled close together, soldiers shivering in their tents, children clutching blankets. 
                
                All of them hoping sleep will bring them comfort.

                By the time you regain control of yourself, it's too late. Your Epiali have spread across the Halfrealm, but doubt clouds their judgement when they barge into dreams. 

                They don't stir mortals' fears from the depths, they don't remind them to make their offerings or say their prayers. 

                There is relief–mortals won't suffer tonight because of you–but also shame. You've failed to raise your nightmare quota. You will receive no worship come dawn.
                *goto nightmarefailure
            *else
                *set morpheusmock true
                Just before you send them out, however, a flash draws your eye. 
                
                There, deep within the Halfrealm's murky depths, so far you can only make out the dark grey of his wings, is Morpheus.

                Your hesitation ripples through the Epiali. You try to stop them but it's too late. They spread into the Halfrealm, but instead of delivering a coordinated assault on mortals' psyches, they barely manage to stir their fears awake.
                    
                Your cheeks are hot with shame. The certainty that you've failed to raise your nightmare quota is like a slap. Worse, come dawn there will be no prayers or offerings in your name. 
                
                All because of stupid Morpheus.
                *goto nightmarefailure
    #Savvy; I want to keep the harmony between the realms.
        You bring your palms together, emptying your mind of everything but what you want your Epiali to do; bring balance.

        *if diplomacy > 50
            *set pantheonplayer %+10
            *set peoplepleaser %+5
            *set worship %+10
            *set nightmaresuccess true
            They carry the command with them as they spread into the Halfrealm, entering dreams cautiously, waking mortals' fears with purpose. 
            
            When they grip, they don't squeeze too tight. When they bite, they don't sink their teeth too deep.

            The certainty that, come dawn, offerings and prayers will be made as they always are settles over you. The gods will be pleased, and mortals will rise feeling grateful, not terrified.
            *goto nightmaresuccess
        *else
            *set pantheonplayer %-10
            *set peoplepleaser %-5
            *set worship %-5
            But the day weighs heavy on your thoughts, tugs at them like an aggravated wasp.

            Your Epiali pick up on the hesitation just as they scatter. You try to call them back but they're already slipping into the Halfrealm, stumbling into their dreams.

            Some are riddled with doubt. It trips them up, makes them fail when they try to drag fears from the depths. The others attempt to make up for it by going overboard, sinking their teeth deep, gripping mortals' psyches tight.

            You wince at the mess of it all. Come dawn, offerings and prayers will be made, but you're certain neither the gods nor mortals have been well served by your spectacular lack of focus.
            *goto nightmarefailure

*label nightmaresuccess
*page_break

Nothing like a job well done to lift your spirits.

Dawn is on its way, however, and there's still plenty to be done. @{(flightstyle) You bring your wings together|You point your shadows forward|You bring your feet together}, and find the Lord of Leukas.
*goto main10

*label nightmarefailure
*page_break

You search for the Lord of Leukas, but the weight of failure slows you down.

Lifting your mood seems impossible, but what choice do you have? Dawn is on its way and there is still plenty to be done.

@{(flightstyle) You wrap your wings around you|You gather your shadows tight, turn them into a little cocoon|You close your eyes, point your toes}. The only thing keeping you from turning back is one goal and one goal alone; 
redemption.

*label main10
*page_break Best Aim High

The islands around Leukas are ruled by kings descended of gods, have borne heroes and birthed myths. They have patron deities who founded their great cities or were chosen by their inhabitants after performing great feats.

They are beloved by the poets.

Leukas may lack their storied reputations, and has yet to claim a patron deity, but that doesn't mean it isn't worthy. Its wines are known far and wide, and soldiers can count on victory, if they sail to battle on a Leukan ship.

After so many visits, you're more than familiar with the sight of its rugged shores. The mountain range at its heart is home to a cedar forest that spills onto the serpentine coastline, where white cliffs, golden shores and green-dusted slopes form a tightly-woven tapestry. 

A temple that has seen better days presides over the edge of a cliff, while the main city is nestled between vineyards and purple sea. 

The scraps of a feast litter its cobbled streets. Freshly-doused fires, empty wine barrels, stumbling stragglers.

It isn't the first time such a scene greets you. Perhaps excessive revelry should be added to the island's list of attributes.

*page_break Pay Its Lord A Visit

His home perches atop a hill, but it's no grander than the houses surrounding it. Same stone walls and terracotta roof, same tidy courtyard and wooden shutters.

Tonight, however, there is one difference. While the other houses are dark and quiet, bright amber light leaks out of his chambers and onto his balcony. 

Where he sits, wide awake and whittling. 

You watch him with a frown, hidden by the knotted vines twisting through the railing.

Seeing him in the flesh like this is

*fake_choice
    #Strange.
        *set Theron %-5
    #Exciting.
        *set Theron %+10
    #Wrong.
        *set Theron %-10
    #Surprising.
        *set Theron %+5

He is both the Lord you encounter in the Halfrealm and not. There, everything is about constructs and abstracts. The physical markers of his mortality are secondary to the emotions it awakens. A wayward thought, a goddess's will–or her daemon's-could transform him into something, into someone, else.

Here, he seems so solid, so corporeal. As though the many versions of him you've known until now were merely sketches, roughly rendered and easily erased, and now you're looking at the muse who inspired them.

Firelight dances on his deep bronze skin, beading it with sweat. His dark curls are thicker, his beard a little less kempt. He doesn't wear finery or jewels, only a short linen tunic and leather sandals that have seen better days.

But it's his hands that strike you the most. They're not the hands of a Lord, touched only by fine things. They are the hands of a craftsman, sinewy and calloused and used to jagged edges.

They move over a half-finished figurine with a surety that is almost god-like, deftly directing wood shavings to the growing pile between his feet.

Your gaze slides to the carving, and you immediately recognize its shape. 

A @{(epiali) snake|bat|raven|cat|spider} that bears an eerie resemblance to your Epiali.

*page_break

You weigh your next move.

House calls aren't in your wheelhouse. You're meant to steal into dreams unnoticed. A whisper in the wind, a shadow in the dark.

Though perhaps you ought to make an exception tonight. Hermes's scroll was very clear. If you don't deliver his message, there will be consequences.

For both of you.

*choice
    #I stick to the shadows; better to wait him out.
        *set startledtheron true
        You perch on the roof, @{(flightstyle) wings tucked in tight|camouflaged by shadows|feather-light on your feet}.

        You might as well have
        *if stealth > 40
            *set maverickgoddess %+10
            *set underworldinfluence %+5
            melted into the night; he doesn't so much as glance skywards.

            Satisfied, you find a comfy spot and wait for sleep to sink its claws into him.

            You wait. 

            And wait.

            And wait.

            Nothing. Every time you peer over the ledge, he's still there. Yawning and rubbing at his eyes, but stubbornly clinging to consciousness.

            Ah, to Tartarus with this.
            *goto theronentrance1
        *else
            *set maverickgoddess %-10
            *set underworldinfluence %-5
            stumbled into a pile of bells. 

            The tiles are far more cracked than you'd anticipated. They crunch beneath your sandals, loud and reverberating. Some even slip off the roof completely, sliding over the ledge and smashing into the balcony below.

            You wince, both at the racket and at the embarrassment burning through you. It only worsens when the mortal speaks.

            "Goddess, are you alright?"       
            *goto theronentrance2
    #I make a bold entrance; I won't be rattled by a mortal.
            Sometimes, it's best to let those who won't heed your messages see you for what you are. 
            
            A goddess of dread, @{(ruthless < 50) borne of darkness|for better or worse}.

            *if demure < 40
                *set pantheonplayer %+10
                *set olympusinfluence %+5
                *set underworldinfluence %+5
                *goto theronentrance1
            *else
                *set Theron %-10
                *set olympusinfluence %-10
                But he doesn't so much as flinch.

                In fact, he doesn't even stop whittling.

                "Hello, Goddess," he greets you calmly.

                Annoyance twists through you. Shame, too.
                *goto theronentrance2
    #Approach with caution; best not to startle him.
        *set friendlytheron true
        You inch closer, @{(flightstyle) wings flickering gently|shadows gently drawn|treading gently}.

        *if ruthless < 40
            *set peoplepleaser %+10
            *set Theron %+10
            It's enough to draw his attention away from his whittling without scaring him.

            You land on the balcony with a muted thud and a reassuring smile.

            He smiles back, and that too is different here. More crooked, and with deeper lines.

            What do you say?

            *fake_choice
                #"Greetings, mortal. I come in peace."
                #"Greetings, mortal. Beautiful night, isn't it?"
                #"Greetings, mortal. Why are you awake?"
            
            *goto noticedbytheron
        *else
            *set peoplepleaser %-10
            *set Theron %-10
            *set annoyedtheron true
            But gentleness doesn't come easy for a goddess of dread.
            *goto theronentrance1

*label theronentrance1
*page_break

You swoop down on the @{(annoyedtheron) balcony, accidentally|balcony,} @{(flightstyle) spreading your wings wide|shaping your shadows into an inky halo|slamming your sandals into the tiled stone}.

His carving knife clatters to the ground and he straightens, startled by your sudden appearance.

*if annoyedtheron
    You wince, trying to smooth out your divinity's sharper edges with what you hope is a reassuring smile.

    "Greetings, mortal," you offer. "Apologies for the rough landing. I didn't mean to scare you."
    *goto noticedbytheron
*else
    You rest your hands on your hips, meeting his wide gaze with @{(startledtheron) an annoyed glare|a triumphant smile}.

    "Mortal. Why are you not asleep?"
                
    He regards you with a mixture of awe and @{(startledtheron) trepidation|trepidation. Good. A deity of your standing deserves nothing less}.
    *goto noticedbytheron

*label theronentrance2

You glance up at the moon, hoping she won't reveal to the rest of the pantheon @{(startledtheron) the extent of your clumsiness|how little awe you inspire}.

Unlikely; she's a consumate gossip.

@{(startledtheron) Sighing, you drag yourself onto the balcony. He knows you're here. You might as well show your face|You clear your throat and, when he frowns, wave at the wood carving}.

@{(startledtheron) "I'm fine," you lie.|"Oh, my apologies."}

*page_break

He nods and sets the @{(epiali) snake|bat|raven|cat|spider} carving down on the table. 

@{(startledtheron) "Good. You gave me a right fright there."|"Is that better?"}

His words only add insult to injury.

"You took too much off the @{(epiali) tail|wings|beak|tail|legs}," you scoff. A desperate attempt at recovering your pride, but one you must make.

His lips twitch upwards. "I disagree."

"Do you make a habit of contradicting deities?"

"Only the ones who are wrong. I like to think of myself as an honest man, you see." He says it lightly, but his next words carry a weight you can't ignore. "Which is why I was hoping you would come. Weaver of Nightmares, I wish to speak to you on behalf of my people. If you would allow me the honor, that is."
*goto main11

*label noticedbytheron
*page_break

@{(friendlytheron) His smile widens|To his credit, his voice doesn't shake when he speaks}.

"Weaver of Nightmares," he says, bowing dutifully. "I was hoping you would come."

"Is that so?"

He sets the @{(epiali) snake|bat|raven|cat|spider} carving down on the table. It's missing @{(epiali) a few scales on the tail|the joints on the left wing|a few feathers on the left wing|a tail|a couple of legs} but, other than that, it's a near perfect rendition of one of your little daemons.

"Indeed. I've been waiting for you to show yourself."

"I wasn't aware I had a schedule to keep," you @{(friendlytheron) say lightly|say}.

@{(annoyedtheron) You didn't mean it in a threatening way, but his lips press together and he shoots you a wary glance|He laughs. It's a practiced sound, meant to charm}.

"Forgive me, Goddess. What I meant to say is that I wish to speak to you on behalf of my people. If you would allow me the honor, that is."

*label main11
*page_break

@{(friendlytheron) You suppose there's no harm in hearing him out|You might as well, if only to get on with your duties}.

"Go on, then."

His shoulders soften with relief.

*page_break

"The people of Leukas are suffering," he begins. "For months now we have been robbed of rest. We make sacrifices, we pour libations, we say our prayers. Yet, every night, the gods ask for more. Then a ship full of heroes docked on our shores two full moons ago."

He may possess the hands of a craftsman, but he has the demeanor of a diplomat. Polite but firm. Earnest but smooth.

"Yes, our island is rich in resources, but only because we never take more than we need, and we always give back what we take. The demands of both the gods and the heroes are taking a toll. It has been a tough winter. Our cellars and storages are depleted and our crops and livestock grow thinner by the day."

He looks to you then, his dark eyes framed by faint, fine lines.

"My people are exhausted and sleep offers them little reprieve. We can't keep up. Worse, we don't know why we are being punished so."

You think of Hermes's hastily written message.

[i]It is paramount you remind him why he shouldn't grow too greedy before Zeus steps in[/i].

*page_break

Still, he isn't wrong about this winter. It [i]has[/i] been a tough one. Then again, your grandmother is a tough goddess. Her and your mother bring spring and summer to the land but, when the Underworld calls its Queen back, Hellas grows cold and unforgiving in her absence. 

More so, if they argue before they part ways.

You think back to the vineyards and orchards you passed on the way to his place. They weren't as fragrant and green as you might expect, but spring has yet to take root. The sheep pens might've looked a little bare, and perhaps there weren't as many goats as there ought to be roaming the mountains.

That doesn't mean he isn't lying. Attempting to garner your sympathy, so that he may continue to defy the gods. 

Many mortals before him have used their people, even their offspring, as pawns to line their pockets and feed their egos.

Something gnaws at you, however. You remember how proud he'd stood at his would-be wedding, how warmly he had smiled at his would-be bride, despite the sorrow lurking behind his eyes.

He seems, for all intents and purposes, like a good man. A fair ruler. So why would he incite the gods' wrath?

*fake_choice
    #I won't take the word of a mortal over the wisdom of the gods.
        *set dutiful %+5
        *set reluctant true
        He must sense your reluctance, for he adds, "If it's my word you doubt, let me prove to you I'm true."
        
        You pause. That is unexpected.
        
        He holds your gaze without flinching. 
    #I need to know what his word is worth, before I risk my skin for it.
        *set cunning %+5
        You must tread carefully. To antagonize the gods would be unwise, but so would ignoring mortals' suffering.

        "Let me prove to you the value of my word," he adds, sensing your hesitation.

        "And how, pray tell, will you manage that?"
    #I believe him and I want to help him, but I need proof that he is true.
        *set ruthless %-5
        *set Theron %+5
        "It's noble of you to stand up to the gods to protect your people. But, for their sake, I need to know your word is true."

        Surprise flickers across his face. As though he had anticipated reluctance from you, but not the reason behind it.

"Ask anything of me, and I will do it. I swear it upon what I hold the most dear; my home," he offers.

You think about it. @{(reluctant) If he's trying to con the gods somehow, his hubris will not go unpunished. The Fates will make sure of it|You can't decide if it's a smart move or a reckless one. But you're willing to go with it, if it gives you a chance to investigate further}.

*page_break But What Will You Ask For?

The Lord of Leukas waits for you to decide, rubbing at a small scar at the base of his neck. A tiny, pinkish slash you've never noticed before. Or perhaps it's never followed him into the Halfrealm.
 
Then he lifts his chin, and his expression reminds you of the one he'd worn at his wedding.

Suddenly, what you must demand of him is obvious.

To know why he fears marriage would:

*fake_choice
    #Give me good leverage to keep him in line if need be, and also impress Hermes.
        *set cunning %+10
    #Satisfy my curiosity. I find myself drawn to the handsome Lord, if not his plight.
        *set Theron %+5
    #Guarantee his people's safety. I will use it against him if I must to make it so.
        *set Theron %+10
        *set dutiful %-10
    #Help keep him in line. I can make him cower more, if I know the root of his fear.
        *set ruthless %+10

You wave your hand, and the Halfrealm manifests around you. Its shadowy waves ripple over brick and vine, its dark currents shift beneath your feet like sand.

A blank canvas for you to fill.

The Lord of Leukas stirs at the sight of it. He doesn't belong here, while he's awake.

Quickly, you will the waters to change. A faded version of the agora takes shape, just as it had been the other night. Music and laughter fill the air. Wine flows freely, meat is passed around on piled-high platters.

"Ah, this." 

His simple chitoniskos and gloomy expressions is at odds with the merriment and finery of the guests.

"Tell me, Lord of Leukas, what is it about commitment that brings you such abject terror?" You glance at his lovely bride, veiled and approaching the altar. "Or perhaps it's beautiful women you fear."

That surprises a chuckle out of him. The Halfrealm blinks in and out of existence around him, as though it can't contain its weight.

"Firstly, it's Theron," he says. Then he gets to his feet, rubbing his hands to get rid of any lingering wood dust. "If I'm going to bare my heart to you, you might as well call me by my name."

*page_break Fair

"Theron," you allow.

"Secondly, it's not committment I fear. Nor beautiful women." He gestures at an older couple at the head of the feasting table. "That is what I fear. Or not having that, I suppose."

The man whispers something into the woman's ear. She shakes her head and gives his chest a gentle shove. A rueful grin softens his features, making him look younger. Her indignation dissolves at the sight of it. She leans into him, pressing a kiss to his spotted cheek.

"Your parents," you say, noticing the resemblance, even in this bastardised memory. He has the man's kind eyes and the woman's strong features.

Theron nods. "They were merely children when they met, but they have loved each other ever since."

Such unions are rare. Even your parents' marriage was an unhappy one, at first.

*page_break

"My people chose me to lead them," he adds. "There's nothing I won't do for them. Including marry for their benefit. But I do fear doing so will mean I won't experience what they have, and that scares me more than I care to admit."

You watch his parents giggle at each other like a pair of besotted youths. @{(background) How sweet.|Is it possible for a god to love so purely, so completely?|Your heart aches with longing. Will you ever know love like that?|Was this what you could've had, if you'd mustered up the courage to reach for it?}

"And yet you have. Admitted it, I mean," you say.

"I gave you my word."

*page_break That He Did

"Still. It is foolish of me. Selfish, too," he says, shaking his head lightly.

@{(marriage) "But you'll do right by your people regardless," you say, feeling a kernel of kinship between you. After all, it's what you yourself will do|"Foolish indeed. Just because marriage is about politics doesn't mean you won't find love outside of it," you observe. What a silly–and rather short-sighted–notion|"It's not selfish. No one should be made to give up their heart. Not for alliances, not for gold, not for anything," you tell him firmly|"That's marriage for you," you offer, determined as ever to avoid being ensnared by it}.

@{(marriage) He nods, but his smile is bittersweet.|He doesn't look convinced.|He doesn't look convinced|His smile is bittersweet}.

"So, Goddess, have I passed the test? Will you speak to the other gods on my behalf, so that my people's suffering may come to an end?" he asks.

You hold his gaze. Will you?

*choice
    #Yes. Mortals shouldn’t be mistreated like this; I'll do everything in my power to help.
        *if dutiful < 60
            *set Theron %+10
            *set peoplepleaser %+10
            *set worship %+20
            "You have proven your word, now let me give you mine; I will aid you however I can to end your people's plight," you tell him.

            Theron places a rugged hand over his heart and bows.

            "Thank you, Goddess. In exchange for your generosity, I will make sure sacrifices are made in your honor in haste."

            *fake_choice
                #"There is no need," I say. He's got enough on his plate.
                    *set ruthless %-10
                    *set Theron %+10
                #I nod solemnly. I will need the extra worship to make myself heard. 
                    *set leadership %+10
                #I find myself too distracted by his dark gaze to answer.
                    *set Theron %+5
                    *set demure %+10
            
            "It shall be done," he declares.
            *goto main12
        *else
            *set Theron %-10
            *set peoplepleaser %-10
            "Rest assured," you tell him. "I will bring your people's plight to the gods."

            You glimpse the frown knotting his brow, as if he were expecting a different response. Perhaps something more rousing, or a vow like the one he made to you. 
            
            You search for the right words, eager to prove yourself, to let him know you're not like the other gods. 
            
            But the moment slips away from you like a soul in flight.
            *goto main12
    #Yes. I'm rather impressed by his charm, and I wouldn't mind seeing him smile again.
        "Consider it done," you tell him. "You're quite the smooth-talker, Theron of Leukas."

        *if demure < 60
            *set Theron %+15
            *set maverickgoddess %+10
            *set worship %+10
            Theron places a rugged hand over his heart and bows, but not before you catch his sly grin, glinting like his laurel crown.

            "You honor me, Goddess."

            He's trouble. Handsome, bound-to-end-badly trouble.

            @{(background) You smile wickedly. Is there a better kind?|The kind that makes your bruised heart give a gentle stir|The kind you've heard poets wax lyrical about. The kind you often wonder about experiencing yourself|The kind that makes you wonder what would happen if you threw caution to the wind this time around}.
            *goto main12
        *else 
            *set Theron %-10
            *set peoplepleaser %-10
            A frown knots his brow at your coy tone. You intended it as a compliment, but it's clear it hasn't landed that way.

            "My apologies, Goddess," he rasps, bowing heavily. "I assure you, my words are far from honeyed. I mean every single one."
            *goto main12
    #Perhaps. While his plight is worthy, his questioning of the gods is worrying.
        *set cautiousrequest true
        "We shall see. If the Fates have deemed your people should suffer, then perhaps that's how it should be."

        *if ruthless > 40
            *set pantheonplayer %+15
            *set worship %+10
            "My apologies, Goddess," he offers, bowing gracefully. "I didn't mean to overstep. I thank you for hearing me out, and will ensure offerings are made in your honor in haste."

            Good. Whatever you decide to do, it will be on your terms, not his.
            *goto main12
        *else 
            *set Theron %-10
            *set peoplepleaser %-10
            *set worship %-10
            "My apologies, Goddess," he rasps, bowing before you.

            But you catch the way he clenches his fists, the anger flickering in his gaze. As though you don't scare him one bit.

            Worse, you have to remind yourself that whatever you decide to do will be on your terms, not his.
            *goto main12
    #Perhaps. I'll investigate, but I won't make any promises beyond that.
        *set cautiousrequest true
        "I thank you for your candor and will look into the matter further," you assure him.
        *if diplomacy > 40
            *set Theron %+5
            *set pantheonplayer %+10
            *set worship %+5
            Polite but firm. Earnest but smooth. Just like he was. 
            
            You share a knowing look.

            "Thank you, Goddess. My people appreciate it."

            You nod, glad for his understanding. It's a delicate situation, one you must handle with care.
            *goto main12
        *else
            *set Theron %-5
            *set peoplepleaser %-5
            *set worship %-5
            You catch the glint of skepticism in his gaze before he lowers it, bowing gracefully.

            "Thank you, Goddess," he says. 
            
            No promises to make offerings in your name or build you a new shrine. You suppose those will come if you deliver what he's after–or take a different, perhaps more drastic approach.

            A diplomat through and through.
            *goto main12

*label main12
*page_break

A flash of pink in the distance alerts you to dawn's approach. Your Epiali sense it too. You can feel them all around you, shaping the Halfrealm, weaving it into nightmares.

"I must get going," you tell Theron.

"Farewell, Goddess."

You cast one last glance at the @{(epiali) snake|bat|raven|cat|spider} carving, then you step into the Halfrealm.

Before you tread its currents, you feel compelled to look back at the mortal.

You find yourself thinking about:

*fake_choice
    #His hands. How might they feel, on a goddess's skin?
        *set Theron %+15
        *set demure %-5
        @{(demure < 50) Rather nice, you'd be willing to bet|You're immediately ashamed of yoursef. What an improper thought!}
    #His longing for love, and the many ways I could use it against him. 
        *set ruthless %+5
        *set Theron %-10
    #His longing for love, and what he is and isn't willing to risk for it.
        *set diplomacy %+5
        *set Theron %+5
    *if cautiousrequest
        #His request. I'm still skeptical about it, and him for that matter.
            *set cunning %+5
            *set Theron %-10
    *if cautiousrequest = false
        #His request. How dare the gods ask so much of him and his people?
            *set dutiful %-5
            *set Theron %+5

Never mind that now; you have daemons to check in with.

You return to the currents shifting around you and welcome their swirling black mass with open arms. You sift through the nightmares they're still unleashing, calling them back on your way to the southern cliffs.

Before you reach them, you see him.

Hovering up ahead, his dark wings drifting around him like smoke, his long, pale hair glowing bright as the moths surrounding it.

*page_break Morpheus

And his Oneroi. The fluttering dameons are the antithesis to your Epiali, even if they serve the same purpose; helping Morpheus deliver dreams. Their delicate wings glint against the dimness, making them look like winged and furry souls.

Despite the swathe of the Halfrealm stretching between you, you can feel the bite of Morpheus's mocking grin.

And the challenge lurking beneath it.

"Rough night, Princess?"

The shadows carry his voice, and the contempt twisting through it. The last word sounds especially sharp.

As it always does, on his lips.

*fake_choice
    #"Now it is."
    #"As if you care."
    #"What do you want?"
    #I simply glower at him.
        *set silent true

He waves you off, unfazed by the loathing in your @{(silent) eyes|tone}.

"I've grown rather bored of beating you back so easily. Thought I'd bear witness to your humiliation this time, shake things up a little."

You clench your fists. The only reason his side of the gate looks so full is because your workload is far greater than his.

He waves a hand and the Halfrealm parts for him, revealing the distant outline of the southern cliffs.

Then he dives for them, a silver-tipped arrow loosed into the fading night.

What do you do?

*choice
    #Beat him back! I chase after him at full speed, determined to put my @{(flightstyle) wings|shadows|sandals} to good use.
        They @{(flightstyle) beat the wind|twist around you like a cyclone|strike the wind} as you charge south.

        *if fitness > 50
            *set Morpheus %+10
            *set pantheonplayer %+10
            *set race 1
            You catch up to Morpheus, who shoots you a bewildered look through the clouds, and savor his shock when you overtake him with ease.

            There's no time for gloating beyond that; there's only the finish line.

            When you finally reach the cave–well before he will, judging by his remote position in the sky–you haven't so much as broken a sweat.
            *goto winnerrun
        *else
            *set maverickgoddess %-10
            *set race 2
            But you're not fast enough. 
            
            Morpheus is ahead of you. So ahead, he's almost at the cave, and has long disappeared by the time you reach the gate, huffing and puffing from the strenuous flight. 
            
            Fates, it was foolish of you to believe a goddess couldn't be out of shape.
            *goto loserrun
    #Beat him back! I lunge after him with gritted teeth, determined to show him no mercy.
        You cut through the clouds, hot on his heels.
            
        Then a colony of gulls flies into the narrowing space between you.

        *if ruthless > 50
            *set Morpheus %+10
            *set maverickgoddess %+10 
            *set race 3
            You don't veer from your path, a single objective on your mind; winning, no matter the cost.

            Some of the birds aren't fast enough. They get caught on your @{(flightstyle) wings, sharp as knives|shadows, thick and sharp|orbit, burning with momentum}. There's a couple of panicked squawks, then their corpses fall from the sky.

            Morpheus halts, distracted–or perhaps horrified–by the ruckus.

            It's all the advantage you need to put a healthy distance between you.

            And reach the cave well before he will.
            
            You even have time to brush the feather's off your clothes before you go through the gate.
            *goto winnerrun
        *else
            *set maverickgoddess %-10
            *set race 4
            You attempt to slow down, afraid you'll hurt them, but it's too late.
            
            You cut into the birds like a swung sword. Their panicked squawks fill your ears as they get caught @{(flightstyle) on the sharp edges of your wings|on your shadows, crushed in their dark midst|in your orbit}.

            For a moment, all you can see is sharp beaks and white down. You swat at them blindly, trying not to feel awful when a couple fall from the sky.

            By the time you've worked your way out of the swarm, huffing and puffing and covered in feathers, Morpheus is long gone. 
            
            You can't help but feel like you've lost your dignity a well as the race.
            *goto loserrun
    #Let him win. I have more important things to worry about, including Leukas and its Lord.
        @{(competitive) It goes against your nature, and your very bones seem to rebel against the idea of losing on purpose. But your duty as a goddess must come first|Some silly competition won't keep you from fulfilling your duty as a goddess}.

        *if leadership > 55
            *set Theron %+10
            *set peoplepleaser %+10
            *set race 5
            *set ambivalent true
            You take your time flying back to the gate, thinking of your next steps, and beginning to plan your angle for the upcoming Messengers' Council meeting.

            Morpheus is long gone by the time you reach the cave. 
            
            You don't care. 
            
            The path ahead is uncertain, but you're confident in your ability to walk it without succumbing to silly distractions.
            *goto loserrun
        *else
            *set peoplepleaser %-10
            *set Theron %-5
            *set race 6
            Then you hear the frantic flap of Morpheus's wings in the distance, remember the smugness in his voice. 

            It's all you can think about on the flight back to the gate.

            Not what next steps you ought to take, not what strategy you'll employ at the upcoming Messengers' Council meeting.

            Just how much you hate @{(competitive) losing|feeling inferior}. 
            
            And Morpheus, of course, who is long gone by the time you reach the gate.
            *goto loserrun
    #Let him win. He’ll be too busy stroking his own ego to get in my way at Council.
        You take your time flying back to the gate, leisurely marvelling at the landscape, thinking of all the ways you may taunt Morpheus the next time you meet.

        *if cunning > 55
            *set Morpheus %+10
            *set maverickgoddess %+10
            *set race 7
            He'll lord his victory over you, confident he has the upper hand.
            
            What a self-absorbed fool, you smile to yourself as you reach the gate.
            *goto loserrun
        *else
            *set maverickgoddess %-10
            *set race 8
            But, just as you're going through the gate, you spot his reflection on the pillar. 
            
            Behhind you in the sky, so far away it's nothing but a silvery flash. 

            As though he thought you wouldn't see it. 

            As though he wanted to let you think you'd beat him, and not the other way around.

            It's more shameful than losing could ever be.
            *goto winnerrun

*label winnerrun
*page_break

The Underworld is calm. Souls wink above you like stars, or moths, as you place a @{(flower) crocus|daffodil|quince flower|nightshade} on your side of the gate.

*if race = 8
    If the Lethe's memory wiping properties worked on deities, you would drink the whole river just to forget the knowledge that he duped you. 

    Or worse, he pities you.

    Still, you will uphold this pretend victory. Perhaps there's still a way you can spin it, use it to your advantage.
    
    Or perhaps, you admit to yourself bitterly, you're trying to dupe yourself, since you couldn't dupe him.

    *choice
        #Continue to the next chapter.
            *finish Chapter 4
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint
*else
    It brings you great satisfaction to think of Morpheus being greeted by such a lovely addition to your sea of @{(flower) violet|yellow|red|dark purple}. So bright and blooming, so impossible to miss.

    You look forward to lording your victory over him.
    
    Soon, you think with a satisfied grin. 
    
    Soon.
    
    *achieve beatmorpheus

    *choice
        #Continue to the next chapter.
            *finish Chapter 4
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint

*label loserrun
*page_break

The Underworld is calm. Souls wink above the gate like stars, or moths, and a fresh poppy has been placed on Morpheus's side, its white petals bright as moonlight.

*if race = 7
    The sight of it isn't so infuriating, when you know you can use it to your advantage. You even lean in and breathe in its scent.

    Self-absorbed fool indeed.
    
    *achieve trickmorpheus
    
    *choice
        #Continue to the next chapter.
            *finish Chapter 4
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint
*elseif race = 5
    You barely register it, making for the palace without giving it a second thought.
    
    *choice
        #Continue to the next chapter.
            *finish Chapter 4
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint
*else
    You have to stop yourself from ripping it up and stomping on it. 

    The sulking you can't hold back, however. 
    
    Looks like he's not the only sore loser in these parts.
    *choice
        #Continue to the next chapter.
            *finish Chapter 4
        *if (not(choice_randomtest)) #Restore to the previous checkpoint.
            *restore_checkpoint